[arch-commits] Commit in svt-av1/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 15:50:16
  Author: foutrelis
Revision: 439089

archrelease: copy trunk to staging-x86_64

Added:
  svt-av1/repos/staging-x86_64/
  svt-av1/repos/staging-x86_64/PKGBUILD
    (from rev 439088, svt-av1/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: svt-av1/repos/staging-x86_64/PKGBUILD (from rev 439088, svt-av1/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-03-06 15:50:16 UTC (rev 439089)
@@ -0,0 +1,49 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Daniel Bermond <dbermond at archlinux.org>
+# Contributor: Thomas Schneider <maxmusterm at gmail.com>
+
+pkgname=svt-av1
+pkgver=0.9.0
+pkgrel=2
+pkgdesc='Scalable Video Technology AV1 encoder and decoder'
+arch=(x86_64)
+url=https://gitlab.com/AOMediaCodec/SVT-AV1
+license=(
+  BSD
+  'custom: Alliance for Open Media Patent License 1.0'
+)
+depends=(glibc)
+makedepends=(
+  cmake
+  git
+  nasm
+  ninja
+)
+_tag=fdf4f36867bba068e221965d12c5975c509845da
+source=(git+https://gitlab.com/AOMediaCodec/SVT-AV1.git#tag=${_tag})
+b2sums=(SKIP)
+
+prepare() {
+  sed '/CMAKE_BUILD_TYPE Release/d' -i SVT-AV1/CMakeLists.txt
+}
+
+pkgver() {
+  cd SVT-AV1
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  export LDFLAGS="$LDFLAGS -Wl,-z,noexecstack"
+  cmake -S SVT-AV1 -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_SHARED_LIBS=ON \
+    -DNATIVE=OFF
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -Dm 644 SVT-AV1/{LICENSE,PATENTS}.md -t "${pkgdir}"/usr/share/licenses/svt-av1/
+}
+
+# vim: ts=2 sw=2 et: