[arch-commits] Commit in libva-intel-driver/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Sun Mar 6 15:50:20 UTC 2022
Date: Sunday, March 6, 2022 @ 15:50:19
Author: felixonmars
Revision: 439090
archrelease: copy trunk to staging-x86_64
Added:
libva-intel-driver/repos/staging-x86_64/
libva-intel-driver/repos/staging-x86_64/PKGBUILD
(from rev 439088, libva-intel-driver/trunk/PKGBUILD)
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Copied: libva-intel-driver/repos/staging-x86_64/PKGBUILD (from rev 439088, libva-intel-driver/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-03-06 15:50:19 UTC (rev 439090)
@@ -0,0 +1,49 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+
+pkgname=libva-intel-driver
+pkgver=2.4.1
+pkgrel=2
+pkgdesc='VA-API implementation for Intel G45 and HD Graphics family'
+arch=(x86_64)
+url=https://01.org/linuxmedia/vaapi
+license=(MIT)
+depends=(
+ libva
+ libdrm
+)
+makedepends=(
+ git
+ meson
+)
+replaces=(libva-driver-intel)
+source=(git+https://github.com/intel/intel-vaapi-driver.git#tag=9a1f0c64174f970a26380d4957583c71372fbb7c)
+sha256sums=('SKIP')
+
+pkgver() {
+ cd intel-vaapi-driver
+
+ git describe --tags
+}
+
+prepare() {
+ cd intel-vaapi-driver
+
+ # Only relevant if intel-gpu-tools is installed,
+ # since then the shaders will be recompiled
+ sed -i '1s/python$/&2/' src/shaders/gpp.py
+}
+
+build() {
+ CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
+ arch-meson intel-vaapi-driver build
+ ninja -C build
+}
+
+package() {
+ DESTDIR="${pkgdir}" meson install -C build
+ install -Dm 644 intel-vaapi-driver/COPYING -t "${pkgdir}"/usr/share/licenses/libva-intel-driver
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list