[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Saturday, March 26, 2022 @ 07:29:30
  Author: grawlinson
Revision: 1176805

addpkg: buildkit 0.10.0-1

Added:
  buildkit/
  buildkit/repos/
  buildkit/trunk/
  buildkit/trunk/PKGBUILD

----------+
 PKGBUILD |   62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

Added: buildkit/trunk/PKGBUILD
===================================================================
--- buildkit/trunk/PKGBUILD	                        (rev 0)
+++ buildkit/trunk/PKGBUILD	2022-03-26 07:29:30 UTC (rev 1176805)
@@ -0,0 +1,62 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Kenneth Endfinger <kaendfinger at gmail.com>
+
+pkgname=buildkit
+pkgver=0.10.0
+pkgrel=1
+pkgdesc='A toolkit for converting source code to build artifacts in a repeatable manner'
+arch=('x86_64')
+url="https://github.com/moby/buildkit"
+license=('Apache')
+depends=('runc' 'containerd')
+makedepends=('git' 'go')
+options=('!lto')
+_commit='068cf686a7e5c3254244d0acc54636f4f393611e'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  # ignore docker tags
+  git describe --tags --exclude 'dockerfile*' | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # create directory for build output
+  mkdir build
+
+  # download dependencies
+  go mod download
+}
+
+build() {
+  cd "$pkgname"
+
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+
+  go build -v \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-linkmode external -extldflags ${LDFLAGS}" \
+    -o build \
+    ./cmd/...
+}
+
+package() {
+  cd "$pkgname"
+
+  # binaries
+  install -vDm755 -t "$pkgdir/usr/bin" build/*
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+  cp -vrt "$pkgdir/usr/share/doc/$pkgname" examples/systemd docs
+  
+}