[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Saturday, March 26, 2022 @ 07:41:37
  Author: grawlinson
Revision: 1176807

addpkg: rootlesskit 1.0.0-1

Added:
  rootlesskit/
  rootlesskit/repos/
  rootlesskit/trunk/
  rootlesskit/trunk/PKGBUILD

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Added: rootlesskit/trunk/PKGBUILD
===================================================================
--- rootlesskit/trunk/PKGBUILD	                        (rev 0)
+++ rootlesskit/trunk/PKGBUILD	2022-03-26 07:41:37 UTC (rev 1176807)
@@ -0,0 +1,69 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Steven Allen <steven at stebalien.com>
+# Contributor: Hugo Osvaldo Barrera <hugo at barrera.io>
+
+pkgname=rootlesskit
+pkgver=1.0.0
+pkgrel=1
+pkgdesc='Native "fake root" for implementing rootless containers'
+arch=('x86_64')
+url="https://github.com/rootless-containers/rootlesskit"
+license=('Apache')
+depends=('glibc' 'shadow')
+makedepends=('git' 'go')
+checkdepends=('openbsd-netcat')
+options=('!lto')
+_commit='1920341cd41e047834a21007424162a2dc946315'
+source=("$pkgname::git+https://github.com/rootless-containers/rootlesskit.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare(){
+  cd "$pkgname"
+
+  # create directory for build output
+  mkdir build
+
+  # download dependencies
+  go mod download
+}
+
+build() {
+  cd "$pkgname"
+
+  # set Go flags
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+
+  go build -v \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-linkmode external -extldflags \"${LDFLAGS}\"" \
+    -o build \
+    ./cmd/...
+}
+
+# tests fail :(
+#check() {
+#  cd "$pkgname"
+#  go test -v ./...
+#}
+
+package() {
+  cd "$pkgname"
+
+  # binaries
+  install -vDm755 -t "$pkgdir/usr/bin" build/*
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+  cp -vr docs "$pkgdir/usr/share/doc/$pkgname"
+}