[arch-commits] Commit in (4 files)

[Caleb Maclennan]

    Date: Tuesday, March 29, 2022 @ 09:16:16
  Author: alerque
Revision: 1177618

Migrate lua{,53,52,51}-lanes from AUR

Added:
  lua-lanes/
  lua-lanes/repos/
  lua-lanes/trunk/
  lua-lanes/trunk/PKGBUILD

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Added: lua-lanes/trunk/PKGBUILD
===================================================================
--- lua-lanes/trunk/PKGBUILD	                        (rev 0)
+++ lua-lanes/trunk/PKGBUILD	2022-03-29 09:16:16 UTC (rev 1177618)
@@ -0,0 +1,59 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: osch <oliver at luced de>
+
+pkgbase=lua-lanes
+_rockname=${pkgbase#lua-}
+pkgname=("$pkgbase" "lua51-$_rockname" "lua52-$_rockname" "lua53-$_rockname")
+pkgname=lua-lanes
+pkgver=3.16.0
+pkgrel=2
+_rockrel=0
+pkgdesc='a lightweight, native, lazy evaluating multithreading library'
+arch=(x86_64)
+url="https://github.com/LuaLanes/$_rockname"
+license=(MIT)
+makedepends=(lua
+             lua51
+             lua52
+             lua53
+             luarocks)
+options=(debug)
+_archive="$_rockname-$pkgver"
+_rock="$_archive-$_rockrel.linux-$CARCH.rock"
+source=("$url/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('4e6d2012ab8b47fdea7d7f778cb1cd196e8987e6a87dd463eeb710097d9b0ca7')
+
+build() {
+	cd "$_archive"
+	for LUAVER in 5.1 5.2 5.3 5.4; do
+		luarocks --lua-version "$LUAVER" \
+			CFLAGS="$CPPFLAGS $CFLAGS -fPIC" \
+			LIBFLAG="$LDFLAGS -shared" \
+			make --pack-binary-rock --deps-mode none -- "$_archive-$_rockrel.rockspec"
+		install -Dm0644 -t "lua$LUAVER/" "$_rock"
+	done
+}
+
+_package() {
+	cd "$_archive"
+	depends=("${pkgname%-*}")
+	luarocks --lua-version "$1" --tree "$pkgdir/usr/" \
+		install --deps-mode none --no-manifest -- "lua$1/$_rock"
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" COPYRIGHT
+}
+
+package_lua-lanes() {
+	_package 5.4
+}
+
+package_lua53-lanes() {
+	_package 5.3
+}
+
+package_lua52-lanes() {
+	_package 5.2
+}
+
+package_lua51-lanes() {
+	_package 5.1
+}