[arch-general] [arch-dev-public] x264 and ffmpeg rebuild

[Sergej Pupykin]

What do you think about ffmpeg-compat package ?

********************
# $Id$

pkgname=ffmpeg-compat
pkgver=20120509
pkgrel=1
pkgdesc="Complete and free Internet live audio and video broadcasting solution for Linux/Unix"
arch=('i686' 'x86_64')
url="http://ffmpeg.org/"
license=('GPL')
depends=(alsa-lib bzip2 gsm lame libpulse libtheora libva
         libvorbis libvpx opencore-amr openjpeg rtmpdump schroedinger
         sdl speex x264 xvidcore zlib)
makedepends=('yasm' 'git' 'libvdpau')
source=(ftp://ftp.archlinux.org/other/ffmpeg/ffmpeg-$pkgver.tar.xz)
md5sums=('a35359e424608f369d380f03e4dc9966')

build() {
  cd "ffmpeg"

  ./configure \
    --prefix=/usr \
    --incdir=/usr/include/ffmpeg-compat \
    --libdir=/usr/lib/ffmpeg-compat \
    --shlibdir=/usr/lib/ffmpeg-compat \
    --enable-libmp3lame \
    --enable-libvorbis \
    --enable-libxvid \
    --enable-libx264 \
    --enable-libvpx \
    --enable-libtheora \
    --enable-libgsm \
    --enable-libspeex \
    --enable-postproc \
    --enable-shared \
    --enable-x11grab \
    --enable-libopencore_amrnb \
    --enable-libopencore_amrwb \
    --enable-libschroedinger \
    --enable-libopenjpeg \
    --enable-librtmp \
    --enable-libpulse \
    --enable-gpl \
    --enable-version3 \
    --enable-runtime-cpudetect \
    --disable-debug \
    --disable-static

  make
}

package() {
  cd "ffmpeg"
  make DESTDIR="$pkgdir" install
  rm -rf $pkgdir/usr/{bin,share}
}
********************

At Thu, 7 Jun 2012 15:36:33 -0400,
Eric Bélanger <snowmaniscool at gmail.com> wrote:
> You might not have noticed but in ffmpeg 0.11, they removed a lot of
> functions and structs that were marked as deprecated in the ffmpeg in
> [extra] so any packages that still use that deprecated stuff won't
> build anymore unless they're patched. As expected, this will take more
> time than a simple rebuild. My remaining package (sox, electricsheep)
> don't build  and I haven't found any patches online. Is there
> documentation on how to port to the newer API? There are hints in the
> header files but I got stuck. Electricsheep build but doesn't work,
> probably because of the line I removed without replacing it (I don't
> know how to replace it), so I'll need to do more work on the patch. If
> someone knows about this stuff, I could post my current patches.