[arch-general] intel-gpu-tools updated PKGBUILD

[Jordan Glover]

I prepared updated PKGBUILD for intel-gpu-tools package[1] which is flagged out-of-date since 2016-12-05.

I updated it to newest version (1.19), updated PGP key to currently used one, upgraded hash to sha256, added new dependencies found by namcap and generally enhanced PKGBUILD to highest Arch standards.

I would be glad if current maintainer or anyone else capable could merge it to official package. There is no official channel for submitting such changes so I decided to send it to this Arch mailinglist.

[1] https://www.archlinux.org/packages/community/x86_64/intel-gpu-tools/

# $Id$
# Maintainer: Daniel Micay <danielmicay at gmail.com>
# Contributor: Mikael Eriksson <mikael_eriksson at miffe.org>
# Originally by: Denis Smirnov <detanator at gmail.com>

pkgname=intel-gpu-tools
pkgver=1.19
pkgrel=1
pkgdesc="Tools for development and testing of the Intel DRM driver"
arch=(i686 x86_64)
license=(MIT)
url='http://cgit.freedesktop.org/xorg/app/intel-gpu-tools/'
depends=('libdrm' 'libpciaccess' 'cairo' 'python' 'xorg-xrandr' 'procps-ng' 'kmod' 'libxv')
makedepends=('swig' 'gtk-doc' 'xorg-util-macros' 'dri2proto')
source=("https://xorg.freedesktop.org/releases/individual/app/${pkgname}-${pkgver}.tar.bz2"{,.sig})
sha256sums=('a49c8ae7c0431c1f33cd9492f83ec4e06e98a48429178e4bd22d9a1a87e3b0f1'
            'SKIP')
validpgpkeys=('775965B85650195ACE77E18D7370055DB74C2475')

build() {
  cd "${pkgname}-${pkgver}"
  export LANG=en_US.UTF-8
  ./configure --prefix=/usr --libexecdir=/usr/lib --disable-tests --without-libunwind
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/intel-gpu-tools/COPYING"
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: PKGBUILD
Type: application/octet-stream
Size: 1106 bytes
Desc: not available
URL: <https://lists.archlinux.org/pipermail/arch-general/attachments/20170817/cbfd52f5/attachment.obj>