[aur-general] PKGBULD validation

[Patrick Ziegler]

Thank you again very much for your insights. I have made the necessary
changes and will try to submit it to the AUR later in the evening, I
will also post the new PKGBUILDs here again just so you can confirm
that there is nothing I still have missed.

notification-mount:
# Maintainer: Patrick Ziegler <p.ziegler96 at gmail dot com>
pkgname="notification-mount"
pkgver=1.0.1
pkgrel=1
pkgdesc="Script to show notification for a block device with mount option"
arch=('any')
url="https://github.com/patrick96/$pkgname"
license=('GPL3')
depends=('python' 'python-gobject' 'python-notify2' 'udevil')
conflicts=("${pkgname}-git")
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
sha256sums=("3cd4421a03e997ae6a99e79851ccfcf8b76a7885821bb982cc59407ea828b138")

package() {
  cd "$srcdir/${pkgname}-${pkgver}"
  install -D -m755 "./notification-mount" "$pkgdir/usr/bin/notification-mount"
  install -D -m644 ./examples/notification-mount.service \
    "$pkgdir/usr/lib/systemd/user/notification-mount.service"
}

# vim:set ts=2 sw=2 et:


notification-mount-git:
# Maintainer: Patrick Ziegler <p.ziegler96 at gmail dot com>
_pkgname="notification-mount"
pkgname="${_pkgname}-git"
pkgver=1.0.1
pkgrel=1
pkgdesc="Script to show notification for a block device with mount option"
arch=('any')
url="https://github.com/patrick96/$_pkgname"
license=('GPL3')
depends=('python' 'python-gobject' 'python-notify2' 'udevil')
makedepends=('git')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("${_pkgname}::git+${url}.git")
md5sums=("SKIP")

pkgver() {
  cd "$_pkgname"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
  cd "$srcdir/$_pkgname"
  install -D -m755 "./notification-mount" "$pkgdir/usr/bin/notification-mount"
  install -D -m644 ./examples/notification-mount.service \
    "$pkgdir/usr/lib/systemd/user/notification-mount.service"
}

# vim:set ts=2 sw=2 et:


2016-09-06 19:57 GMT+02:00 Rafael Fontenelle <rafaelff at gnome.org>:
> Just as complement of what Eli said:
>
>> makedepends=('git')
>
> If not fetching the source code via git (like to Eli suggested for
> notification-mount
> package), please remember to remove this setting from your PKGBUILD.
>
>>  cd "$srcdir/$pkgname" || exit
>
> There is no need for verification like "|| exit" or "|| false" as error
> status are already identified and treat.  Try adding a command to change to
> a nonexistent directory and see what makepkg returns. ;)
>
>
> Best Regards,
> Rafael Fontenelle