[aur-general] PKGBUILD git remote branch issue

[Ralf Mardorf]

On Wed, 2018-11-07 at 08:38 -0500, Eli Schwartz via aur-general wrote:
> As per the PKGBUILD(5) man page, use:
> 
> source=("git://example.com/reponame.git#FOO=BAR")
> 
> where FOO is either:
> - tag
> - branch
> - commit
> 
> and BAR is the corresponding revision you wish to check out (in this
> case the branch name is "gtk3")
> 
> So, #FOO=BAR would be #branch=gtk3

Thank you,

unfortunately it doesn't work.

[rocketmouse at archlinux claws-mail-gtk3-git]$ ls
PKGBUILD
[rocketmouse at archlinux claws-mail-gtk3-git]$ makepkg -s
==> Making package: claws-mail-gtk3-git 3.17.0-1 (Wed 07 Nov 2018 03:27:22 PM CET)
[snip]
==> Starting prepare()...
==> Starting pkgver()...
==> Updated version: claws-mail-gtk3-git 3.16.0.r463.g04185a6e4-1
==> Starting build()...
^C

[rocketmouse at archlinux tmp]$ git clone git://git.claws-mail.org/claws.git
[snip]
[rocketmouse at archlinux tmp]$ cd claws/
[rocketmouse at archlinux claws]$ git fetch origin
[rocketmouse at archlinux claws]$ git branch --track gtk3 origin/gtk3
Branch 'gtk3' set up to track remote branch 'gtk3' from 'origin'.
[rocketmouse at archlinux claws]$ ./autogen.sh
[snip]
claws-mail 3.17.0git153
[snip]

Regards,
Ralf
-------------- next part --------------
pkgname=claws-mail-gtk3-git
pkgver=3.17.0
pkgrel=1
pkgdesc='A GTK3 based e-mail client - git checkout'
arch=('i686' 'x86_64')
license=('GPL3')
url='https://www.claws-mail.org/'
depends=('gtk3' 'gnutls' 'startup-notification' 'enchant' 'gpgme' 'libetpan' 'compface'
	'libsm' 'dbus-glib' 'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('git' 'spamassassin' 'bogofilter' 'valgrind'
	# dependencies for plugins
	'libgdata' 'libnotify' 'libcanberra' 'poppler-glib' 'pygtk' 'dillo'
	# deps to build the docs
	'docbook-utils' 'texlive-core')
optdepends=('python2:           needed for some tools and python plugin'
	'perl:              needed for some tools and perl plugin'
	'spamassassin:      adds support for spamfiltering'
	'bogofilter:        adds support for spamfiltering'
	'libnotify:         for notification plugin'
	'libcanberra:       for notification plugin'
	'dbus:              for notification plugin'
	'libxml2:           for rssyl plugins'
	'curl:              for vcalendar, rssyl and spamreport plugins'
	'libarchive:        for archive plugin and various other plugins'
	'libytnef:          for tnef_parse plugin'
	'libgdata:          for gdata plugin'
	'poppler-glib:      for pdf viewer plugin'
	'ghostscript:       for pdf viewer plugin'
	'dillo:             for html viewer plugin')
replaces=('sylpheed-claws' 'claws-mail-extra-plugins')
conflicts=('claws-mail-extra-plugins' 'claws-mail')
provides=('claws' 'claws-mail')
source=('claws-mail::git://git.claws-mail.org/claws.git#branch=gtk3')
sha256sums=('SKIP')

pkgver() {
	cd claws-mail/

	if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
		printf '%s.r%s.g%s' \
			"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
			"$(git rev-list --count ${GITTAG}..)" \
			"$(git rev-parse --short HEAD)"
	else
		printf '0.r%s.g%s' \
			"$(git rev-list --count master)" \
			"$(git rev-parse --short HEAD)"
	fi
}

prepare() {
	cd claws-mail/

	# fixes for python2
	sed -i 's@^#!.*python.*@#!/usr/bin/python2@' tools/*.py
	git update-index --assume-unchanged tools/*.py
}

build() {
	cd claws-mail/

	# run autogen without options - it runs ./configure for us, but we need to fix python first
	NOCONFIGURE=1 ./autogen.sh

	# fixes for python2
	export PYTHON="/usr/bin/python2"
	sed -i 's:python -c:python2 -c:g' configure

	# add --enable-alternate-addressbook to the options to use the
	# new/alternate address book
	# do not forget to add claws-contacts to the dependencies then
	./configure \
		--build=$HOSTTYPE-arch-linux-gnu \
		--prefix=/usr \
		--disable-jpilot \
		--disable-maintainer-mode \
		--disable-manual \
		--disable-static \
		--enable-bogofilter-plugin \
		--enable-crash-dialog \
		--enable-enchant \
		--enable-gnutls \
		#--enable-gtk3 \
		--enable-ldap \
		--enable-pgpmime-plugin \
		--enable-silent-rules \
		--enable-spamassassin-plugin
		#--help
	make

	# build extra tools
	cd tools/
	make
}

package() {
	cd claws-mail/

	make DESTDIR="${pkgdir}" install

	# install extra tools
	# all executables and .conf files ; only top directory
	cd tools
	for FILE in $(find -maxdepth 1 -type f -and -perm /111 -or -name '*.conf'); do
		install -D -m0755 ${FILE} "${pkgdir}"/usr/lib/claws-mail/tools/${FILE}
	done
}