[aur-requests] [PRQ#7438] Request Rejected

[Bruno Pagani]

Le 07/02/2017 à 20:04, John D Jones III via aur-requests a écrit :

>> firefox-developer was uploaded I guess when Mozilla stopped officially
>> calling it "aurora"? So their respective maintainers should figure it
>> out between them, while we spectators assume good faith.
>>
>
> Well, as far as I know, the Firefox Developer package differs for
> vanilla Aurora in that it includes a number of tools for Web
> Development that may not be available with Aurora Builds
> https://www.mozilla.org/en-US/firefox/developer/ for reference, well,
> actually I stand corrected, it seems they've shifted the Aurora
> channel to only support Android builds, though it might still be
> possible to run it on a Desktop? I'm not sure, I never used the Aurora
> build. I took over Firefox Developer when I discovered it's existence.
> I took the AUR v3 PKGBUILD and updated it and uploaded it to AUR v4. I
> presume that means that it was an orphaned pkg on the v3 AUR, so how
> that came to be initially vs Aurora, I don't actually know.

I think our emails crossed each others… But this makes me realize I’ve
made a mistake, Firefox Developer started in November 2014 and not 2015.
Time pass. For future reference, they intend to make the developer tools
a system addon FWIR.

> I do attempt to update the versions within a few days of it being
> marked out of date or a comment comes in, though life happens and
> sometimes it takes an extra day or two for me to get around to it.
> Anyways, all that said, when I get off work, I'll first, update it to
> the latest version, then look into making it a bit more capable of
> checking it's own sha512 sums similar to the nightly-fr pkgbuild after
> that.
>
> I appreciate all the feedback about my pkgbuild, it helps me to feel
> like I really am making a contribution, albeit small, to the Open
> Source and Arch Linux communities.

I’ve tailored firefox-nightly-fr PKGBUILD for use in firefox-developer,
I’ve joined it (+updated .desktop file) to this email. It won’t work for
now since the checksums are not online, but those should be back
tomorrow. Don’t hesitate to ask if they are things you don’t understand
in my PKGBUILD. ;)

Cheers,
Bruno
-------------- next part --------------
A non-text attachment was scrubbed...
Name: firefox-developer.desktop
Type: application/x-desktop
Size: 625 bytes
Desc: not available
URL: <https://lists.archlinux.org/pipermail/aur-requests/attachments/20170207/4b0d779b/attachment-0001.bin>
-------------- next part --------------
_name=firefox
_channel=developer
_lang=en-US
pkgname=${_name}-${_channel}
pkgdesc="Standalone Web Browser from Mozilla — Developer build (also formerly Aurora)"
url="https://www.mozilla.org/${_lang}/${_name}/${_channel}"
_version='53.0a2'
pkgver=53.0a2.20170207
pkgrel=1
arch=('i686' 'x86_64')
license=('MPL' 'GPL' 'LGPL')
depends=('dbus-glib' 'gtk2' 'gtk3' 'libxt' 'nss' 'mime-types')
optdepends=('pulseaudio: audio support'
            'ffmpeg: h.264 video'
            'hunspell: spell checking'
            'hyphen: hyphenation')
_url="https://download-installer.cdn.mozilla.net/pub/${_name}/nightly/latest-mozilla-aurora"
_src="${_name}-${_version}.${_lang}.linux"
_file_i686="${_src}-i686.tar.bz2"
_file_x86_64="${_src}-x86_64.tar.bz2"
_sums_i686="${_src}-i686.checksums"
_sums_x86_64="${_src}-x86_64.checksums"
source=("${pkgname}.desktop" 'vendor.js')
source_i686=("${_url}"/{"${_file_i686}","${_sums_i686}"{,.asc}})
source_x86_64=("${_url}"/{"${_file_x86_64}","${_sums_x86_64}"{,.asc}})
sha512sums=(
    'b3fc6c0f61ceb98942a6106678353dd4a44ce2d435feb702ec85c93044158cfce8aff8291a9a41ab1633f9f12af33daaabc17127edaf10c10ca8bd4df7d77cd2'
    'bae5a952d9b92e7a0ccc82f2caac3578e0368ea6676f0a4bc69d3ce276ef4f70802888f882dda53f9eb8e52911fb31e09ef497188bcd630762e1c0f5293cc010'
)
_getsum_i686="$(curl -O ${_url}/${_sums_i686})"
_getsum_x86_64="$(curl -O ${_url}/${_sums_x86_64})"
sha512sums_i686=("$(grep ${_file_i686} ${_sums_i686} | grep sha512 | cut -d " " -f1)" 'SKIP' 'SKIP')
sha512sums_x86_64=("$(grep ${_file_x86_64} ${_sums_x86_64} | grep sha512 | cut -d " " -f1)" 'SKIP' 'SKIP')
validpgpkeys=('14F26682D0916CDD81E37B6D61B7B526D98F0353') # Mozilla’s GnuPG release key

pkgver() {
  echo "${_version}.$(curl -s ${_url}/${_name}-${_version}.en-US.linux-${CARCH}.txt | head -n1 | cut -c -8)"
}

package() {
  OPT_PATH="opt/${pkgname}"

  # Install the package files
  install -d "${pkgdir}"/{usr/bin,opt}
  cp -r ${_name} "${pkgdir}"/${OPT_PATH}
  ln -s "/${OPT_PATH}/${_name}" "${pkgdir}"/usr/bin/${pkgname}

  # Install .desktop files
  install -Dm644 "${srcdir}"/${pkgname}.desktop -t "${pkgdir}"/usr/share/applications

  # Install icons
  SRC_LOC="${srcdir}"/${_name}/browser
  DEST_LOC="${pkgdir}"/usr/share/icons/hicolor
  for i in 16 32 48
  do
      install -Dm644 "${SRC_LOC}"/chrome/icons/default/default${i}.png "${DEST_LOC}"/${i}x${i}/apps/${pkgname}.png
  done
  install -Dm644 "${SRC_LOC}"/icons/mozicon128.png "${DEST_LOC}"/128x128/apps/${pkgname}.png

  # Disable auto-updates
  install -Dm644 "${srcdir}"/vendor.js -t "${pkgdir}"/${OPT_PATH}/browser/defaults/preferences

  # Use system-provided dictionaries
  rm -rf "${pkgdir}"/${OPT_PATH}/{dictionaries,hyphenation}
  ln -sf /usr/share/hunspell "${pkgdir}"/${OPT_PATH}/dictionaries
  ln -sf /usr/share/hyphen "${pkgdir}"/${OPT_PATH}/hyphenation
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 520 bytes
Desc: OpenPGP digital signature
URL: <https://lists.archlinux.org/pipermail/aur-requests/attachments/20170207/4b0d779b/attachment-0001.asc>