[aur-requests] [PRQ#7438] Request Rejected

Wed Feb 8 16:25:26 UTC 2017

Le 08/02/2017 à 16:53, John D Jones III a écrit :

>  and while
>> jnbek isn’t inactive and answered he wanted to keep this package, it has
>> not yet been updated, while firefox-dev is working almost OK.
>>
>> Regards,
>> Bruno
>>
>
> I should probably apologize for my much slower response time. I had
> two major spinal surgeries in 2015, this last one in December was
> quite a bit more painful than was expected. That said, I haven't been
> keeping up with my email anywhere near my usual everyday perusal. As
> stated in my previous email, I do try to get to out of date requests
> and 'hey this thing is broken' comments/emails as quickly as possible,
> I apologize for not notifying everyone much sooner as to the state of
> my maintainership. Right now, I am specifically focusing on my most
> popular and/or most actively developed pkgbuilds to keep them up to
> date. I did drop the ball with firefox-developer, knowing that updates
> occur sometimes in a matter of minutes and I will endeavor to prevent
> any further interruptions between the development process and pkgbuild
> updates. Of note, I did get the version updated last night and it
> should be working fine, if this is not the case, please let me know.

Sure, I understand your reasons. But do not hesitate to eventually state
them on the package page, and if you lack time to care about some
packages there is no shame in orphaning them or accepting comaintainers. ;)

> Now, Bruno:
> What about the pulseaudio dependencies?

Try to play a video or any sound in Firefox without having pulseaudio
installed, and tell me what happen. But I’m giving you the answer right
away: a nice scroll notification telling you that pulseaudio is required
to actually play sound in Firefox. So this should be added as an
optional dependency (I, for one, live OK without sound in my browser,
and prefer that above installing pulseaudio), just like ffmpeg is for
h264 playback support.

Note that Firefox didn’t dropped support for ALSA altogether, but it’s a
compile time option off by default, so not in official mozilla builds.

Also, regarding the PKGBUILD update, things have become even more
simple, because the new build process (responsible for the missing
checksum) added PGP sigs to the tarball itself. So checksums can be
skipped altogether. Please find attached (I’m still unsure whether the
list accept attachment, so if there is nothing just tell me) a new
version that you can use, which will work without the checksum (but
doesn’t work just now, see below for reason and a fix).

When comparing with your package, the change are the following:

– added all the known optdeps ;
– proper handling of different sources for different CARCH (the way you
do it currently is wrong) ;
– make use of PGP sigs (note that at the moment this doesn’t work since
the sig doesn’t match, but it works if you change the domain part of the
url from https://download-installer.cdn.mozilla.net/ to
https://ftp.mozilla.org/pub/firefox/nightly/latest-mozilla-aurora/) ;
– make use of system hyphen and hunspell ;
– install more icons to hicolor.

Cheers,
Bruno
-------------- next part --------------
A non-text attachment was scrubbed...
Name: firefox-developer.desktop
Type: application/x-desktop
Size: 625 bytes
Desc: not available
URL: <https://lists.archlinux.org/pipermail/aur-requests/attachments/20170208/7dd481bc/attachment.bin>
-------------- next part --------------
_name=firefox
_channel=developer
_lang=en-US
pkgname=${_name}-${_channel}
pkgdesc="Standalone Web Browser from Mozilla — Developer build (also formerly Aurora)"
url="https://www.mozilla.org/${_lang}/${_name}/${_channel}"
_version='53.0a2'
pkgver=53.0a2.20170207
pkgrel=1
arch=('i686' 'x86_64')
license=('MPL' 'GPL' 'LGPL')
depends=('dbus-glib' 'gtk2' 'gtk3' 'libxt' 'nss' 'mime-types')
optdepends=('pulseaudio: audio support'
            'ffmpeg: h.264 video'
            'hunspell: spell checking'
            'hyphen: hyphenation')
_url="https://download-installer.cdn.mozilla.net/pub/${_name}/nightly/latest-mozilla-aurora"
_src="${_url}/${_name}-${_version}.${_lang}.linux"
source=("${pkgname}.desktop" 'vendor.js')
source_i686=("${_src}-i686.tar.bz2"{,.asc})
source_x86_64=("${_src}-x86_64.tar.bz2"{,.asc})
sha512sums=(
    'b3fc6c0f61ceb98942a6106678353dd4a44ce2d435feb702ec85c93044158cfce8aff8291a9a41ab1633f9f12af33daaabc17127edaf10c10ca8bd4df7d77cd2'
    'bae5a952d9b92e7a0ccc82f2caac3578e0368ea6676f0a4bc69d3ce276ef4f70802888f882dda53f9eb8e52911fb31e09ef497188bcd630762e1c0f5293cc010'
)
sha512sums_i686=('SKIP' 'SKIP')
sha512sums_x86_64=('SKIP' 'SKIP')
validpgpkeys=('14F26682D0916CDD81E37B6D61B7B526D98F0353') # Mozilla’s GnuPG release key

pkgver() {
  echo "${_version}.$(curl -s ${_url}/${_name}-${_version}.en-US.linux-${CARCH}.txt | head -n1 | cut -c -8)"
}

package() {
  OPT_PATH="opt/${pkgname}"

  # Install the package files
  install -d "${pkgdir}"/{usr/bin,opt}
  cp -r ${_name} "${pkgdir}"/${OPT_PATH}
  ln -s "/${OPT_PATH}/${_name}" "${pkgdir}"/usr/bin/${pkgname}

  # Install .desktop files
  install -Dm644 "${srcdir}"/${pkgname}.desktop -t "${pkgdir}"/usr/share/applications

  # Install icons
  SRC_LOC="${srcdir}"/${_name}/browser
  DEST_LOC="${pkgdir}"/usr/share/icons/hicolor
  for i in 16 32 48
  do
      install -Dm644 "${SRC_LOC}"/chrome/icons/default/default${i}.png "${DEST_LOC}"/${i}x${i}/apps/${pkgname}.png
  done
  install -Dm644 "${SRC_LOC}"/icons/mozicon128.png "${DEST_LOC}"/128x128/apps/${pkgname}.png

  # Disable auto-updates
  install -Dm644 "${srcdir}"/vendor.js -t "${pkgdir}"/${OPT_PATH}/browser/defaults/preferences

  # Use system-provided dictionaries
  rm -rf "${pkgdir}"/${OPT_PATH}/{dictionaries,hyphenation}
  ln -sf /usr/share/hunspell "${pkgdir}"/${OPT_PATH}/dictionaries
  ln -sf /usr/share/hyphen "${pkgdir}"/${OPT_PATH}/hyphenation
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 520 bytes
Desc: OpenPGP digital signature
URL: <https://lists.archlinux.org/pipermail/aur-requests/attachments/20170208/7dd481bc/attachment.asc>